零基础开发 era 游戏 #5 变量的声明 / 定义

ARRAY:(index_a):(index_b):(index_c)  ; 最多三维 四维数组定义时就会报错
ARRAY:index_a:index_b:index_c        ; 当下标不存在歧义时 括号可以省略

ARRAY:(idx + 1)                      ; 当下标需要先计算时 必须用括号包起来
ARRAY:idx + 1                        ; 视为 (ARRAY:idx) + 1
; 某种程度上可以认为 [: 运算符] 比 [其他运算符] 优先

ARRAY:0                              ; 当下标为 0 时（取数组第一个值）可以直接省略
ARRAY == ARRAY:0                     ; 实际上 RESULT / LOCAL / ARG 其实都是数组

@SYSTEM_TITLE
    LOCAL:10 = 123   ; SYSTEM_TITLE 函数里的 LOCAL:10
    CALL TEST        ; 调用 TEST
    ; 你改的是 TEST 里的 LOCAL:10
    ; 跟我 SYSTEM_TITLE 里的 LOCAL:10 有什么关系？
    PRINTV LOCAL:10  ; 原样打印 123
    QUIT


@TEST
    LOCAL:10 = 999  ; 修改 TEST 函数里的 LOCAL:10
    RETURN

@SYSTEM_TITLE
    CALL TEST(11, 13, 777)
    PRINTV RESULT  ; 打印 24（11 + 13）
    QUIT


@TEST, ARG:0, ARG:1, ARG:1100
    LOCAL = ARG:0 + ARG:1
    RETURN LOCAL

RESULT,100
COUNT,100
A,-1
B,-1
C,-1
D,-1
E,-1
F,-1
G,-1

@SYSTEM_TITLE
    WHILE 1
        TWAIT 1000, 1
        WINDOW_TITLE '= @"%GETTIMES()% 编程，很神奇吧？"
    WEND
    QUIT

@TEST
    #DIM 一个数值变量
    #DIMS 一个字符串变量
    ; 你当然可以用中文作为变量名 但非常不推荐
    ; 你可能会想: 很多 era 游戏本体就是大量使用日文变量名 这是事实
    ; 但这是非常不好的习惯 这也是事实 不要学他们
    #DIM num                               ; 没有设定初始值的数值
    #DIMS word                             ; 没有设定初始值的字符串
    #DIM a_num = 123                       ; 设定初始值的数值
    #DIMS words = "noot noot"              ; 设定初始值的字符串
    #DIMS many_words = "are", "you", "ok"  ; 设定初始值的字符串数组

@TEST
    #DIM num

    num = 32        ; 十进制
    num = 0x20      ; 十六进制 hexadecimal
    num = 0b100000  ; 二进制 binary
    num = 1p5       ; 1 × 2 的 5 次方（即二进制的 1 后面 5 个 0）

    num = 1e5       ; 1 × 10 的 5 次方（即 1 后面 5 个 0）

@TEST
    ; 没有定义数组上限 自动取初始值的元素数量
    #DIM three_num = 1, 2, 3

    ; 定义的数组上限超过初始值的元素数量 没有指定初始值的其他项均为默认初始值
    #DIM hundred_num, 100 = 4, 5, 6
    ; hundred_num:99 == 0

    ; 初始值元素数量超过定义的数组上限
    ; 报错「初期値の数が配列のサイズを超えています」
    #DIM error_num, 2 = 7, 8, 9

    ; 字符串数组变量同理
    #DIMS three_str = "A", "B", "C"

@SYSTEM_TITLE
    #DIM timer = 10
    WHILE timer--
        CALL TEST
    WEND
    QUIT


@TEST
    #DIM DYNAMIC dynamic_cnt
    #DIM normal_cnt
    dynamic_cnt += 1
    normal_cnt += 1
    PRINTFORML dynamic={dynamic_cnt} normal={normal_cnt}

@TEST
    ; 没有定义数组上限 自动取初始值的元素数量
    #DIM CONST const_array = 1, 2, 3

    ; 初始值与定义的数组上限不符
    ; 报错「定数の初期値の数が配列のサイズと一致しません」
    #DIM CONST const_big_array, 100 = 4, 5, 6

    ; 字符串数组变量同理
    #DIMS CONST const_str_array = "A", "B", "C"

@SYSTEM_TITLE
    #DIM num = 10
    PRINTVL num     ; 10
    CALL TEST(num)  ; 10 + 5
    PRINTVL num     ; 15
    QUIT


@TEST(argv)
    #DIM REF argv
    argv += 5

@SYSTEM_TITLE
    #DIM array, 10
    array = 10
    array:1 = 20
    array:2 = 30
    CALL TEST(array:1)
    QUIT


@TEST(list)
    #DIM REF list
    PRINTL 尽管你写的是传 array:1
    PRINTL 其实传的还是 array 这一整个数组
    PRINTFORML list={list} 其实是 list:0={list:0}
    PRINTFORML 其他元素也一起传进来了 list:1={list:1} list:2={list:2}

@TEST
    #DIM CONST the_num = 123
    #DIMS CONST the_str = "ABC"
    #DIMS temp = "第一个字符串变量", "第二个字符串变量"
    PRINTFORML temp:0=%temp:0%
    PRINTFORML temp:1=%temp:1%
    temp:0 = 右边的内容原封不动的赋值给左边 "包括引号和空格" {the_num} %the_str%
    temp:1 '= "右边的内容需要为一个完整的字符串 " + GETTIMES() + @" {the_num} %the_str%"
    PRINTFORML temp:0=%temp:0%
    PRINTFORML temp:1=%temp:1%